greaterThan(QT_MAJOR_VERSION, 4) {
    QT += widgets

    !ios:QT += printsupport

    greaterThan(QT_MINOR_VERSION, 1) {
        macx:QT += macextras
    }
}

DEFINES += QSCINTILLA_DLL

INCLUDEPATH += $$[QT_INSTALL_HEADERS]

LIBS += -L$$[QT_INSTALL_LIBS]

CONFIG(debug, debug|release) {
    mac: {
        LIBS += -lqscintilla2_qt$${QT_MAJOR_VERSION}_debug
    } else {
        win32: {
            LIBS += -lqscintilla2_qt$${QT_MAJOR_VERSION}d
        } else {
            LIBS += -lqscintilla2_qt$${QT_MAJOR_VERSION}
        }
    }
} else {
    LIBS += -lqscintilla2_qt$${QT_MAJOR_VERSION}
}
