#compdef dumpadm

_dumpadm() {
	local -a content

	content=(
		"kernel"\:"Kernel memory pages only"
		"all"\:"All memory pages"
		"curproc"\:"Kernel memory pages plus curproc pages"
	)

	_arguments -s \
		'-n[dont run savecore on reboot]' \
		'-u[update dump configuration from dumpadm.conf]' \
		'-y[run savecore on reboot]' \
		'-c[set dump content]:dump content:(($content))' \
		'-d[set dump device]:block devices:_files -g "*(-%b)"' \
		'-m[set minfree size ]:' \
		'-s[set the savecore directory]:directory:_files -/' \
		'-r[alternate root directory]:directory:_files -/'
}

_dumpadm "$@"
