#compdef madison rmadison

_arguments \
  '(-a --architecture)'{-a,--architecture=}':arch:_sequence _deb_architectures -a "all source" -' \
  '(-b --binary)'{-b,--binary-type=}':type:(deb udeb)' \
  '(-c --component)'{-c,--component=}':component:_values -s , "component list" main contrib non-free non-free-firmware' \
  '(-g --greaterorequal)'{-g,--greaterorequal} \
  '(-G --greaterthan)'{-G,--greaterthan} \
  '(-h --help)'{-h,--help} \
  '(-s --suite)'{-s,--suite=}':suite:_values -s , "suite list" stable testing unstable oldstable oldoldstable' \
  '(-r --regex)'{-r,--regex} \
  '(-S --source-and-binary)'{-S,--source-and-binary} \
  '(-u --url)'{-u,--url=}':url:_values -s , "url alias" debian new qa ubuntu all udd archive ports' \
  '--version' \
  '(--no-conf --noconf)'{--no-conf,--noconf} \
  '*:package:_deb_packages avail'

