reset
set pm3d
set datafile separator '\t'
set border 0
unset xtics
unset ytics
unset ztics
set cbrange [0:100]
set view 42,100, 1.3
set colorbox horiz user origin .1,.1 size .8,.04
#
# set palette color rgbformula -33,-13,-10
#
set title "Gliese star catalog - 7 parsec neighborhood centered on Earth"
set cblabel "Luminosity" offset 0,1
#
splot 'nearmap.csv' using 5:6:7:11 with points pt 6 ps 2 pal notitle, \
      ''            using 5:6:7:11 with points pt 7 ps 1 pal notitle, \
      '' using 5:6:7:2 with labels font "Helvetica,9" left \
	   point pt 0 offset 1,0 notitle
#
pause -1
